Excel Table absolute reference for cells, columns, and rows

One of the first things we learn in Excel is the magic of the $ symbol. It freezes the row or column, so the cell reference does not change when copying a formula. This is known as an absolute reference. With the introduction of Tables came a different (and more semantic) way to reference cells, called structured references. However, structured references don’t follow the same principles as the standard A1 style referencing system we usually use. As a result, the $ symbol approach won’t work. But don’t worry; by the end of this post, you will know how to create an Excel Table absolute reference.

Table of Contents

• Scenario
• Excel Table absolute reference for column
• Relative and absolute reference for cells in the same row
• Relative and absolute reference for any cell
• Absolute references in Headers and Totals
• Conclusion

Watch the video

Watch on YouTube

Scenario

The examples in this post all use the following Table.

The Table shows the costs a Safari Park might incur for owning different types of animals. The Table name is myTable, whilst it’s not a great name, it will work for this example.

Excel Table absolute reference for column

When using structured references, whole columns are referenced with this syntax:

tableName[columnName]

Using the example data to sum the Total column, the formula would be:

=SUM(myTable[Total])

If this were dragged or copied to another column, the formula would change automatically. If copied to the left, it would change to:

=SUM(myTable[Qty])

If copied to the right, it would revert to the first column in the table and changes to:

=SUM(myTable[Animal])

NOTE: This is one of the quirks when working with Table columns. Once a structured column reference reaches the end of the Table, it loops back to the start.

If using the standard A1 style referencing, we could add the $ signs and change the range from G2:G9 (a relative reference) to $G$2:$G$9 (an absolute reference). But we can’t use $ with the structured references found in Tables.

To achieve the same result, we need to add more square brackets, a colon ( : ), and repeat the column name.

=SUM(myTable[[Total]:[Total]])

The difference between the relative and absolute reference for columns is shown in blue above.

If you have been using Tables for a while, you will notice this is the same syntax as when referencing multiple columns.

=SUM(myTable[[Food]:[Other]])

The reference above shows how to sum the columns from Food to Other in the example data. This means multi-column references selected using the mouse are absolute by default. 

To create a relative multi-column reference, we need to remove the outer square brackets and repeat the table name, as shown below.

=SUM(myTable[Food]:myTable[Other])

Or you could include each column individually within the calculation as shown below, which achieves the same result.

=SUM(myTable[Food],myTable[Keepers],myTable[Other])

Relative and absolute reference for cells in the same row

When using Tables, the syntax to reference a cell in the same row is as follows.

=[@Total]    or    =[@[Total Value]]

NOTE: the 2nd syntax in the example above is where the header contains a space or special character.

If the formula is contained in a cell outside the Table, the Table name must also be added:

=myTable[@Total]    or    =myTable[@[Total Value]

To make a row reference absolute, the same principles apply as we saw for column references. It does not matter if the reference is inside or outside the Table; the Table name is required for both.

=myTable[@[Total]:[Total]]

To reference multiple columns, the syntax is similar.

=SUM(myTable[@[Food]:[Other]])

The reference above shows how to sum the columns from Food to Other from the example data. This is an absolute column reference.

To create a relative multi-column reference, we need to remove the outer square brackets.

=SUM([@Food]:[@Other])    or    =SUM(myTable[@Food]:myTable[@Other])

NOTE: The @ symbol serves the same purpose as when working with dynamic arrays; it calculates based on the implicit intersection. Check out this post for more information: Dynamic arrays in Excel

Relative and absolute reference for any cell

In the section above, we considered the scenario where the column was absolute while the row was based on a cell in the same row. However, to reference a row which is not in the same row different approach.

The INDEX function returns a cell reference or value from a specified location in a range or array. As a simple example, look at the following formula:

=INDEX($G$2:$G$9,1)

This formula would always return the first row from cells G2:G9. To return the second cell from the same range, the formula would be

=INDEX($G$2:$G$9,2)

Therefore, using INDEX with structured references allows us to refer to any individual cell in the range. For example, the following returns the first item from the Total column.

=INDEX(myTable[Total],1)

Tow is an absolute reference, but the column is relative; therefore this is a mixed reference.

To create a full relative reference, we must also find a way to count row numbers within the INDEX.

The following uses ROW(A1) to calculate a relative row reference. ROW(A1) evaluates to 1. When dragged down, ROW(A2) evaluates to 2. Therefore ROW creates the relative number to use in the INDEX function.

=INDEX(myTable[Total],ROW(A1))

The formula above is a fully relative table reference.

Absolute references in Headers and Totals

Referencing the Header and Total rows within a Table is slightly different again. This is because Headers and Totals inherently have absolute row references but not column references.

The relative reference for Headers is shown below:

=myTable[[#Headers],[Food]]

To turn the Header reference into an absolute reference, add the section highlighted below.

=myTable[[#Headers],[Food]:[Food]]

If you’ve read this post all the way through, then the multi-column absolute reference will not surprise you. The formula to count the column headings is shown below.

=COUNTA(myTable[[#Headers],[Food]:[Other]])

And the multi-column relative reference will not surprise you either.

=COUNTA(myTable[[#Headers],[Food]]:myTable[[#Headers],[Other]])

The examples in this section all include the Header row (#Headers). To reference the Total row, use #Totals instead.

Conclusion

With a Table, the different syntax to provide relative or absolute references can be quite subtle. An @ or square bracket out of place can cause an error that can be incredibly frustrating to find. It is easier to start with a valid reference and then adjust it, rather than typing the reference from scratch.

As with all things, practice is vital. Before long, creating an Excel Table absolute reference will be second nature.

Related posts:

• Running total in an Excel Table
• How to use Excel Table within a data validation list (3 ways)

---

What next?

Discover how you can automate your work with our Excel courses and tools.