VBA code draw rectangles around selected cells

When creating reports, it is sometimes necessary to highlight cells to draw attention to them.  The most obvious method to achieve this is to change a Cell’s border color, I did that for many years.  It’s quick to apply, but the pain comes when it’s time to remove the color,  the formatting of every cell needs to be changed back on each box to it’s original style.

That’s where the following macros come into play.  Rather than applying cell border colors, it draws rectangle shapes around the selected cells.

Create the rectangles

First, select all the Cell ranges which you want to highlight.  You can even select multiple ranges all at the same time.  Run the Macro below.   Rectangles will be drawn perfectly around the selected cells.

VBA Code:

Sub addRedBox()

Dim redBox As Shape
Dim selectedAreas As Range
Dim i As Integer
Dim tempShape As Shape

'Loop through each selected area in active sheet
For Each selectedAreas In Selection.Areas

    'Create a rectangle
    Set redBox = ActiveSheet.Shapes.AddShape(msoShapeRectangle, _
        selectedAreas.left, selectedAreas.top, _
        selectedAreas.Width, selectedAreas.Height)

    'Change attributes of shape created
    redBox.Line.ForeColor.RGB = RGB(255, 0, 0)
    redBox.Line.Weight = 2
    redBox.Fill.Visible = msoFalse
    'Loop to find a unique shape name
    Do
        i = i + 1
        Set tempShape = Nothing
        
        On Error Resume Next
        Set tempShape = ActiveSheet.Shapes("RedBox_" & i)
        On Error GoTo 0
    
    Loop Until tempShape Is Nothing
    
    'Rename the shape
    redBox.Name = "RedBox_" & i
Next

End Sub

Delete all the rectangles

Having created all the rectangles in the previous macro, we need a simply way to remove the boxes.

In the code above, every rectangle created was renamed to begin with “RedBox_”.  The following macro loops through all the shapes and deletes only those which begin with “RedBox_”.

VBA Code:

Sub deleteRedBox()

Dim shp As Shape

'Loop through each shape on active sheet
For Each shp In ActiveSheet.Shapes

    'Find shapes with a name starting with "RedBox_"
    If left(shp.Name, 7) = "RedBox_" Then

        'Delete the shape
        shp.Delete

    End If

Next shp

Conclusion

The whole point of these two macros is to apply and remove shapes quickly.  Therefore, I recommend saving these codes in your Personal Macrobook, and include them on a custom tab of the ribbon, then they will be available instantly at any time.

---

What next?

Discover how you can automate your work with our Excel courses and tools.