VBA code to copy, move, delete and manage files

Automating processes with VBA can involve copying, moving, deleting and managing lots of files.  Thankfully, VBA has many built-in functions to undertake these tasks for us.  These files do not necessarily need to be Excel workbooks; they can be any file type.

Table of Contents

Download the example file: Join the free Insiders Program and gain access to the example file used for this post.

File name: 0041 VBA copy, move, delete and manage files.zip

Check if a file exists

If any actions are performed on a file that does not exist, the VBA code will error.  As a result, checking for a file’s existence can be one of the most common action we perform.

The code below will display True or False in a message box to indicate if the file exists.

Sub CheckIfFileExists()

'Check if a file exists
MsgBox Dir("C:\Users\marks\Documents\Folder\Text.xlsx") <> ""

End Sub

The code below uses an If statement to carry out different actions depending on if the file does or does not exist.

Sub PerformActionIfFileExists()

Dim filePath As String

filePath = "C:\Users\marks\Documents\Folder\FileName.xlsx"

If Dir(filePath) <> "" Then

    'Insert action for if the file exists
    'This example displays a message box
    MsgBox filePath & " exists."

Else

    'Insert actions if the file does not exist
    'This example displays a message box
    MsgBox filePath & " does not exist."

End If

End Sub

When regularly checking for the existence of files, it can be easier to have a reusable function within a Module to be called upon when required.

'Reusable function to check if a file exists
Function DoesFileExist(filePath) As Boolean

DoesFileExist = Dir(filePath) <> ""

End Function

The code below shows how to call the reusable function as part of an If statement.

Sub UseTheFunction()

Dim myFile As String

myFile = "C:\Users\marks\Documents\Folder\FileName.xlsx"

'Call the reusable function to check for file existence
If DoesFileExist(myFile) = True Then

    'Insert action for if the file exists
    'This example displays a message box
    MsgBox "The file exists."

End If

End Sub

Rename a file

The code below renames a file.

Sub RenameAFile()

'Rename a file
Name "C:\Users\marks\Documents\Folder\CurrentFileName.xlsx" _
    As "C:\Users\marks\Documents\Folder\NewFileName.xlsx"

End Sub

If the target filename is already an existing file, the code will error.  Therefore, it is good practice to check if the source and target file names are already in use.

Check out this post for more examples of using VBA to rename files.

Moving a file

The code to move a file is the same syntax as the code to rename a file.

Sub MoveAFile()

'Move a file
Name "C:\Users\marks\Documents\FileName.xlsx" As _
    "C:\Users\marks\Documents\New Folder\FileName.xlsx"

End Sub

Copying a file

Copying a file retains the existing file, but creates a duplicate version of it in a new location.

Sub CopyAFile()

'Copy a file
FileCopy "C:\Users\marks\Documents\Folder\Original File.xlsx", _
    "C:\Users\marks\Documents\New Folder\Copied File.xlsx"

End Sub

If the target filename is already an existing file, the code will error.  Therefore, it is good practice to check if the source and target file names are already in use.

Delete files

Deleting files removes them completely.  Files deleted using VBA are not sent to the recycle bin, and since there is no undo functionality it can be quite dangerous.  Take extra care to ensure the code does what you expect it to.

The following code deletes a specific file.

Sub DeleteSpecificFile()

'Delete a specific file
Kill "C:\Users\marks\Documents\Folder\DeleteMe.xlsx"

End Sub

The code below deletes files using a wildcard.  In this circumstance, it deletes all files with a .xlsx file extension.

Sub DeleteFilesWithWildcards()

'Delete all .xlsx files using the * wildcard character
Kill "C:\Users\marks\Documents\Folder\*.xlsx"

End Sub

The example below deletes all the files in a folder by using wildcard characters.

Sub DeleteAllFilesInFolder()

'Delete all files from a folder using two * wildcard characters
Kill "C:\Users\marks\Documents\Folder\*.*"

End Sub

Common wildcard characters are:

CharacterDescription
* (asterisk)Any number of characters
? (question mark)Any individual characters

The example below applies the * (asterisk) and ? (question mark) wildcard characters

'Delete all .xlsx or .xlsm files from a folder, but not .xls files
'as the ? wildcard must be atleast on character in length
 Kill "C:\Users\marks\Documents\Folder\*.xls?"

Get file attributes

Each files has specific attributes, for example, they can be read-only, hidden or system files etc..

The code below checks if a file is read-only.

Sub GetFileAttributes()

Dim myFile As String

myFile = "C:\Users\marks\Documents\Folder\ReadOnlyFile.xlsx"

'If the file is Read-Only, display message box
If (GetAttr(myFile) And vbReadOnly) <> 0 Then

    MsgBox "The file is Read only"

End If

End Sub

To check for other attributes, replace vbReadOnly in the code above with the required settings.

VBA Name of attributeEnumeratorDescription
vbNormal0Files with no attributes (default setting)
vbReadOnly1Read-only files
vbHidden2Hidden files
vbSystem4System files
vbVolume8Volume label
vbDirectory16Directories

Discover how you can automate your work with our Excel courses and tools.

Excel Academy

Excel Academy
The complete program for saving time by automating Excel.

Excel Automation Secrets

Excel Automation Secrets
Discover the 7-step framework for automating Excel.

Office Scripts Course

Office Scripts: Automate Excel Everywhere
Start using Office Scripts and Power Automate to automate Excel in new ways.

2 thoughts on “VBA code to copy, move, delete and manage files”

  1. Good morning Mark,

    Thank you so much for posting the handy set of VBA routine for managing files, some of which will I will certainly be using to enhance a user-interface to automate an Excel -to-Word application I am developing.

    As I can imagine you are inundated with request for advice, I will certainly understand if you are unable to respond to this thank-you note, but on the off chance you might be able to offer some help, here’s an issue I am trying to deal with:

    Although I have successfully developed a routine to extract text items from an excel workbook to a Word document using bookmarks in the Word document itself, I am having problem with a copying a chart
    (graph). Although the the actual extraction from Excel and transfer is working fine, the “layout” of the chart defaults to “In line with text” option and disrupts the format of the textual content of the document. The issue is easily resolvable by manually clicking on the transferred chart and then, from the displayed Layout options, selecting in “Front of text” one. Doing this enables the chart to be moved (floated) into the desired position . I believe there must be a simple way of programmatically conditioning the “Front of text” option, but so far I haven’t been able to figure out how to do it, so any help/advice you might be able to offer would be gratefully received and I’m sure would be appreciated by other coders you might be able to assist.

    Many thanks in advance.

    Best regards,

    Danny

    Reply
    • Hi Danny – It’s not something I have ever tried. Have you tried to use the Macro recorder in Word to capture the relevant code?

      Reply

Leave a Comment